Опубликован: 19.09.2008 | Доступ: свободный | Студентов: 658 / 70 | Оценка: 4.50 / 5.00 | Длительность: 21:25:00
Лекция 21:

Утилиты работы с монадами

< Лекция 20 || Лекция 21: 12 || Лекция 22 >
Аннотация: А вот в этой лекции мы вернемся с вами к рассмотрению монад. Если вы помните, мы уже начали изучение монад ввода-вывода. Здесь мы уже поподробней рассмотрим работу с монадами, узнаем какими функциями она пользуется, рассмотрим основные классы, ну и конечно же, не забудем упомянуть о библиотеке Monad

module Monad (
    MonadPlus(mzero, mplus),
    join, guard, when, unless, ap,
    msum,
    filterM, mapAndUnzipM, zipWithM, zipWithM_, foldM, 
    liftM, liftM2, liftM3, liftM4, liftM5,

    - ...и то, что экспортирует Prelude
    Monad((>>=), (>>), return, fail),
    Functor(fmap),
    mapM, mapM_, sequence, sequence_, (=<<), 
    ) where

class  Monad m => MonadPlus m  where
    mzero  :: m a
    mplus  :: m a -> m a -> m a

join             :: Monad m => m (m a) -> m a
guard            :: MonadPlus m => Bool -> m ()
when             :: Monad m => Bool -> m () -> m ()
unless           :: Monad m => Bool -> m () -> m ()
ap  :: Monad m => m (a -> b) -> m a -> m b

mapAndUnzipM     :: Monad m => (a -> m (b,c)) -> [a] -> m ([b], [c])
zipWithM         :: Monad m => (a -> b -> m c) -> [a] -> [b] -> m [c]
zipWithM_        :: Monad m => (a -> b -> m c) -> [a] -> [b] -> m ()
foldM            :: Monad m => (a -> b -> m a) -> a -> [b] -> m a
filterM  :: Monad m => (a -> m Bool) -> [a] -> m [a]

msum   :: MonadPlus m => [m a] -> m a

liftM            :: Monad m => (a -> b) -> (m a -> m b)
liftM2           :: Monad m => (a -> b -> c) -> (m a -> m b -> m c)
liftM3           :: Monad m => (a -> b -> c -> d) ->
                               (m a -> m b -> m c -> m d)
liftM4           :: Monad m => (a -> b -> c -> d -> e) ->
                               (m a -> m b -> m c -> m d -> m e)
liftM5           :: Monad m => (a -> b -> c -> d -> e -> f) ->
                               (m a -> m b -> m c -> m d -> m e -> m f)

Библиотека Monad определяет класс MonadPlus и обеспечивает некоторые полезные операции над монадами.

20.1. Соглашения об именах

Функции в этой библиотеке используют следующие соглашения об именах:

  • Суффикс "M" всегда обозначает функцию в категории Клейсли (Kleisli): m добавляется к результатам функции (карринг по модулю) и больше нигде. Так, например,
    filter  ::            (a ->   Bool) -> [a] ->   [a]
      filterM :: Monad m => (a -> m Bool) -> [a] -> m [a]
  • Суффикс "_" меняет тип результата (m a) на (m ()). Таким образом (в Prelude):
    sequence  :: Monad m => [m a] -> m [a] 
    sequence_ :: Monad m => [m a] -> m ()
  • Приставка "m" обобщает существующую функцию на монадическую форму. Таким образом, например:
    sum  :: Num a       => [a]   -> a
      msum :: MonadPlus m => [m a] -> m a

20.2. Класс MonadPlus

Класс MonadPlus определен следующим образом:

class  Monad m => MonadPlus m  where
    mzero  :: m a
    mplus  :: m a -> m a -> m a

Методы класса mzero и mplus являются соответственно нулем и плюсом для монады.

Списки и тип Maybe являются экземплярами класса MonadPlus, таким образом:

instance  MonadPlus Maybe  where
    mzero                 = Nothing
    Nothing `mplus` ys    = ys
    xs      `mplus` ys    = xs

instance  MonadPlus []  where
    mzero = []
    mplus = (++)

20.3. Функции

Функция join является обычным оператором объединения монад. Он используется для того, чтобы убрать один уровень монадической структуры, проектируя его связанный аргумент во внешний уровень.

Функция mapAndUnzipM устанавливает соответствие (отображает) между своим первым аргументом и списком, возвращая результат в виде пары списков. Эта функция главным образом используется со сложными структурами данных или с монадой преобразований состояний.

Функция zipWithM обобщает zipWith на произвольные монады. Например, следующая функция выводит на экран файл, добавляя в начало каждой строки ее номер:

listFile :: String -> IO ()
listFile nm =
  do cts <- readFile nm
     zipWithM_ (\i line -> do putStr (show i); putStr ": "; putStrLn line)
               [1..]
               (lines cts)

Функция foldM аналогична foldl, за исключением того, что ее результат инкапсулируется в монаде. Обратите внимание, что foldM работает над перечисленными аргументами слева направо. При этом могла бы возникнуть проблема там, где (>>) и "сворачивающая функция" не являются коммутативными.

foldM f a1 [x1, x2, ..., xm ]
==  
    do
      a2 <- f a1 x1
      a3 <- f a2 x2
      ...
      f am xm

Если требуется вычисление справа налево, входной список следует обратить (поменять порядок элементов на обратный).

Функции when и unless обеспечивают условное выполнение монадических выражений. Например,

when debug (putStr "Отладка\n")

выведет строку "Отладка\n", если булево значение debug равняется True, иначе не выведет ничего.

Монадическое повышение операторов повышает функцию до монады. Аргументы функции рассматриваются слева направо. Например,

liftM2 (+) [0,1] [0,2] = [0,2,1,3]
liftM2 (+) (Just 1) Nothing = Nothing

Во многих ситуациях операции liftM могут быть заменены на использование ap, которое повышает применение функции.

return f `ap` x1 `ap` ... `ap` xn

эквивалентно

liftMn f x1 x2 ... xn
< Лекция 20 || Лекция 21: 12 || Лекция 22 >