Опубликован: 04.07.2006 | Доступ: свободный | Студентов: 5532 / 659 | Оценка: 4.11 / 3.96 | Длительность: 11:08:00
Лекция 7:

Кратко о приложениях для сетей. Windows API

< Лекция 6 || Лекция 7: 123 || Лекция 8 >
Аннотация: Практическая работа "Создание Browser" демонстрирует возможность создания приложений для сетей. Далее обсуждается возможность включения готовых фрагментов Windows в пользовательские приложения.

Кратко о приложениях для сетей

При разработке приложений для сетей могут использоваться сочетания кода языка гипертекста, документы ActiveX и т.д. Ограничимся написанием программы-Browser; для создания таких приложений разработан элемент управления WebBrowser, обладающий методами, обеспечивающими, например, навигацию; событиями, связанными с загрузкой файлов и т.д. После создания Browser'a его возможности могут интегрироваться в приложение и пользователь получает доступ в сеть из своей пользовательской Visual Basic-программы.

Практическая работа 47. Создание Browser

  1. Последовательность действий:
    • вывести элемент управления WebBrowser: меню Проект \to Компоненты \to Microsoft Internet Controls \to OK, вывести его на форму, рис. 7.1, центр,
    • создать на форме элемент управления StatusBar: меню Проект \to Компоненты \to Microsoft Windows Common Controls \to OK \to вывести на форму с панели элементов управления элемент управления StatusBar, рис. 7.1 внизу,
    • свойству Style, созданного на форме элемента управления (рис. 7.1 вверху) СomboBox присвоить значение 0; очистить свойство Text,
    • создать 5 объектов CommandButton: Command1, Caption = New URL; Command2, Caption = STOP; Command3, Caption = HOME; Command4, Caption = FORWARD; Command5, Caption = BACK. Cвойствам Picture присвоить значения - имена файлов с рисунками, см. рис. 7.1 вверху,
  2. найти (меню Windows Пуск \to Поиск) файлы tearoom.htm, readmevb.htm, Register.htm (или другие файлы формата *.htm, имеющиеся в наличии), скопировать их на дискету,
  3. ввести код, данный ниже, пояснения даны под комментариями,
  4. стартовать проект; в поле элемента управления WebBrowser выводится стартовый файл (здесь) Running Bithday.htm, см. код; в поле комбинированного списка имеется одна запись "Running Bithday", в поле объекта StatusBar - соответствующая запись,
  5. ввести в текстовое поле СomboBox последовательно имена файлов и соответствующие пути: tearoom.htm, readmevb.htm, Register.htm, нажимая после каждого ввода командную кнопку Command1 (New URL) - в поле WebBrowser выводятся новые страницы, список СomboBox заполняется именами файлов. Наблюдать содержимое поля StatusBar,
  6. использовать кнопки Command3 (HOME), Command4 (FORWARD), Command5 (BACK) - в поле WebBrowser выводятся ранее использованные страницы (рис. 7.1).
' описание переменной, предназначенной для хранения 
' стартового URL
Private start As String

' инициализация переменной, хранящей стартовый URL и
' передача параметра процедуре навигации 
' Web Browser1.Navigate start
Private Sub Form_Load() 
ErhaltAdr
makeNavig start
End Sub

' присвоить переменной значение - имя файла
Private Sub ErhaltAdr()
start = "file://A:\Running Birthday.htm"
End Sub

' навигация браузера. В результате навигации 
' устанавливается соединение с соответствующим узлом 
' и начинается загрузка файла, указанного в URL
Private Sub makeNavig(Adr As String) 
WebBrowser1.Navigate Adr
End Sub

' командной кнопкой можно остановить передачу и 
' загрузку файла
Private Sub WebBrowser1_DownloadBegin() 
Command2.Enabled = True
End Sub

Private Sub Command2_Click() 
WebBrowser1.Stop
End Sub

' заканчивается загрузка файла, указанного в URL, 
' останавливать нечего
Private Sub WebBrowser1_DownloadComplete() 
Command2.Enabled = False
' указать имя файла (URL) в статусной строке
StatusBar1.SimpleText = WebBrowser1.LocationName 
StatusBar1.SimpleText = "LOAD FROM: " & WebBrowser1.LocationName
With ComboBox1
' включить в список ComboBox имя файла 
' текущего URL и исключить 5-й элемент списка,
' если список полон
.AddItem WebBrowser1.LocationName
' .ListIndex = 0
If .ListCount > 5 Then
.RemoveItem 5
End If
End With
End Sub

' перемещения к ранее использованным страницам
Private Sub Command5_Click() 
WebBrowser1.GoBack
End Sub

Private Sub Command4_Click()
WebBrowser1.GoForward
End Sub

Private Sub Command3_Click()
makeNavig start
End Sub

' после ввода пути и имени файла в поле ComboBox (здесь 
' используется тип доступа "file:\\путь :") сделать щелчок
' на кнопке для реализации навигации
Private Sub Command1_Click() 
makeNavig ComboBox1.Text
End Sub
Browser

Рис. 7.1. Browser
< Лекция 6 || Лекция 7: 123 || Лекция 8 >
Константин Новков
Константин Новков

Лекция 3: 2

Для создания возможности использования объектов файловой системы нужно подключить библиотеку DLL, содержащую эти объекты: меню Разработать > Ccылки > Microsoft Scriptlet Component (сделать щелчок на соответствующем элементе управления CheckBox).

Не могу найти меню Разработать (Develop)>Links и т.д.

антонина квасова
антонина квасова