Файловый ввод-вывод.

Ввод-вывод для файлов произвольного доступа и бинарных файлов

Для последовательных файлов запись данных всегда происходит в конец файла, а чтение после открытия производится с самого начала. Для бинарных файлов и файлов произвольного доступа операция чтения выполняется оператором Get, операция записи ѕ оператором Put. Эти операции позволяют читать и записывать записи в произвольном порядке. Установить нужную позицию записи или чтения можно, вызвав оператор Seek:

Seek [#]номер-файла, позиция

Параметр номер-файла - номер открытого в режиме Random или Binary файла; позиция - число от 1 до 2 147 483 647, определяющее место в файле, куда будут помещены данные следующим оператором Put или откуда они будут считаны следующим оператором Get. Для файлов произвольного доступа позиция задает номер записи в файле, для бинарных и последовательных файлов - номер байта (символа). Иногда, в процессе поиска позиции необходимо передвинуться вперед или назад на некоторое число записей относительно текущей позиции. Функция Seek может быть использована для того, чтобы определить текущую позицию:

Seek(номер-файла)

Она возвращает число в диапазоне от 1 до 2 147 483 647. Для файлов произвольного доступа - это номер следующей считываемой или записываемой записи, для файлов, открытых в остальных режимах, - позиция байта, в которой будет выполняться следующая операция

Операторы Put и Get позволяют сами установить позицию, переопределив, тем самым, позицию, установленную оператором Seek. Эти операторы имеют одинаковый, простой и ясный синтаксис:

Put [#]номер-файла, [номер-записи], переменная
Get [#]номер-файла, [номер-записи], переменная

Параметры этих операторов имеют следующий смысл:

• Параметр номер-файла - номер открытого в режиме Random или Binary файла;
• номер-записи - числовое выражение, определяющее позицию в файле, куда будут помещены вводимые данные или откуда данные будут прочитаны. Для файлов произвольного доступа - это номер записи в файле, для бинарных файлов - порядковый номер байта в файле. Нумерация записей (байтов) в файле начинается с 1. Если параметр номер-записи опустить, данные будут записаны (прочитаны) в текущую позицию. Уже говорилось, что установить текущую позицию можно оператором Seek. Отметим также, что после выполнения операторов Get и Put текущей становится позиция очередной записи (байта), следующей за только что прочитанной записью (байтом). Заметьте, даже если этот параметр опущен, разделяющая запятая все же остается в операторе вызова.
• Параметр переменная - имя переменной, значение которой должно быть записано в файл (в которую будет прочитана запись).

Вот простой пример записи и чтения в файл произвольного доступа:

Public Sub Test1()
	Dim N As Integer
	Open Path & "test.1" For Random Access Read Write As #1 Len = 2
	N = 1
	Put 1, 1, N
	Get 1, 1, N
	Debug.Print N, LOF(1)
	N = 2
	Put 1, 2, N
	Get 1, 2, N
	Debug.Print N, LOF(1)
	N = 3
	Put 1, 1, N
	Get 1, 1, N
	Debug.Print N, LOF(1)
	Close #1
		
End Sub

Используемая здесь функция LOF(номер-файла) возвращает длину файла в байтах. Заметьте, будет создан файл из двух записей, поскольку третий по счету оператор Put изменяет значение первой записи, так что перед закрытием функция LOF возвратит значение 4.

Но давайте рассмотрим чуть более серьезный пример. Рассмотрим работу с файлом, который назовем "Товары.9". Этот файл будет содержать информацию о товарах. Код товара будет служить ключом записи. Зная код товара, можно будет найти запись в файле. На практике, когда формальным ключом записи, как в нашем случае, является ее порядковый номер, всегда задается некоторая функция, которая реальный ключ, возможно заданный несколькими параметрами, преобразует в порядковый номер. В нашем примере, чтобы не вводить таких преобразований, будем полагать, что код товара изменяется в пределах от 1 до N и, следовательно, он может служить формальным ключом записи. Вот как задается пользовательский тип, описывающий товар:

Type Товар
	КодТовара As Integer
	Наименование As String * 10
	Цена As Integer
End Type

Создадим файл, хранящий записи этого типа. Чтобы можно было проследить за деталями, наш файл будет содержать не более 10 записей. Мы используем случайные числа для генерирования записей этого файла. Вот три процедуры, решающие эту задачу:

Public Sub CreateRec(Rec As Товар)
	'Создает запись типа Товар
	Randomize
	Rec.КодТовара = Int(Rnd * 9 + 1) 'Код от 1 до 9
	Rec.Наименование = "Товар" & Rec.КодТовара
	Rec.Цена = Int(Rnd * 99 + 1) * Rec.КодТовара
	
End Sub

Public Sub PrintRec(Rec As Товар)
	'Печать записи о товаре
	Debug.Print "Код Товара:", Rec.КодТовара, "Цена:", Rec.Цена
End Sub

Public Sub CreateRandomFile()
	Dim i As Integer, NewRec As Товар
	Open Path & "Товары.9" For Random Access Write As #1 Len = Len(NewRec)
	'Создаем 10 записей
	For i = 1 To 10
		Call CreateRec(NewRec)
		Call PrintRec(NewRec)
		Put #1, NewRec.КодТовара, NewRec
		
	Next i
	Debug.Print "Файл Товары.9 успешно создан"
	Debug.Print "Размер файла", LOF(1)
Close #1
End Sub

Приведем результаты отладочной печати:

Код Товара:	7			Цена:			294 
Код Товара:	3			Цена:			141 
Код Товара:	3			Цена:			84 
Код Товара:	1			Цена:			18 
Код Товара:	6			Цена:			246 
Код Товара:	8			Цена:			472 
Код Товара:	8			Цена:			376 
Код Товара:	7			Цена:			483 
Код Товара:	2			Цена:			168 
Код Товара:	8			Цена:			224 
Файл Товары.9 успешно создан
Размер файла	112

Прокомментируем эти процедуры и полученные результаты. Первая процедура генерирует запись, используя датчик случайных чисел ѕ функцию Rnd. Ранее в своих примерах мы уже использовали эту функцию и подробно говорили о том, как она работает. Вторая процедура позволяет вывести запись в окно отладки. Основной является процедура CreateRandomFile, в которой открывается файл "Товары.9" как файл с произвольным доступом, открытый для записи. При открытии, что очень важно, мы не забыли указать длину записи. Поскольку файл предназначен для хранения значений переменных типа "Товар", то этот тип и определяет длину записи, ѕ она равна 14 байтов (10 байтов занимает строка постоянной длины и 4 байта требуется для двух полей типа Integer).В процедуре 10 раз генерируется новая запись и 10 раз выполняется оператор Put, производящий запись в файл. Но как показывают результаты отладочной печати, некоторые коды повторяются, поэтому в таких случаях происходит обновление содержимого записи. В данном примере только 6 записей имеют уникальный код, и 4 раза происходило обновление уже созданных записей. Важно обратить внимание на длину созданного файла. Анализируя эту характеристику, можно понять, что файл содержит 8 записей, а не 10 и не 6. Дело в том, что длина файла произвольного доступа определяется записью с максимальным номером. Пусть в файле есть запись с максимальным номером M. И пусть добавляется новая запись с номером N, большим M. В этот момент в файле будут созданы новые записи с номерами от M+1 до N включительно. Запись с номером N будет действительно записана, а остальные получат значения по умолчанию, в соответствии с соглашениями, принятыми в VBA. Так что, если в файл пишется одна единственная запись с ключом 10000, то это означает, что в файле автоматически появляется 10000 записей и таков будет его размер. В нашем примере максимальный код равен 8,ѕ отсюда и размер файла равен 112 = 8*14

Рассмотрим теперь работу с этим файлом. Мы приведем две процедуры. Первая из них ведет последовательную обработку всех записей файла, читая их друг за другом. Вторая ѕ случайным образом генерирует запрос на получение записи файла со случайным ключом. Вот эти процедуры:

Public Sub PrintFile()
 Dim N As Integer, i As Integer, Code As Integer
	Dim MyRec As Товар
	'Открыть файл Товаров для обработки
	Open Path & "Товары.9" For Random Access Read As #1 Len = Len(MyRec)

	N = LOF(1) \ Len(MyRec) 'Число	записей
	Debug.Print "Число	записей файла-- ", N
	For i = 1 To N
		'Установить позицию
		Seek 1, i
		'Получить запись с заданным кодом
		Get #1,, MyRec
		Call PrintRec(MyRec)
	Next i
	Close #1
End Sub

Вот на какие моменты следует обратить внимание. Файл открывается теперь для чтения и при открытии корректно указывается длина записи. Для подсчета числа записей файла используется упоминавшаяся функция LOF. Заметьте, мы используем оператор Seek для установки позиции, но это скорее для проформы, поскольку в данной ситуации Seek не изменяет уже установленной позиции. Вот результаты работы этой процедуры:

Число	записей файла--		8 
Код Товара:	1			Цена:			18 
Код Товара:	2			Цена:			168 
Код Товара:	3			Цена:			84 
Код Товара:	0			Цена:			0 
Код Товара:	0			Цена:			0 
Код Товара:	6			Цена:			246 
Код Товара:	7			Цена:			483 
Код Товара:	8			Цена:			224

Мы уже пояснили, почему в файле оказалось 8 записей и почему часть из них имеет нулевые значения.

Следующая процедура работы с этим файлом демонстрирует возможность работы с ним, когда доступ к записям осуществляется в произвольном порядке, что, впрочем, демонстрировалось и при создании этого файла:

Public Sub WorkWithFile()
	Dim N As Integer, i As Integer, Code As Integer
	Dim MyRec As Товар
	Randomize
	'Открыть файл Товаров для обработки
	Open Path & "Товары.9" For Random Access Read As #1 Len = Len(MyRec)

	N = Int(Rnd * 9 + 1) 'Число обрабатываемых записей
	Debug.Print "Число обрабатываемых записей -- ", N
	For i = 1 To N
		Code = Int(Rnd * 9 + 1)
		'Установить позицию
		Seek 1, Code
		'Получить запись с заданным кодом
		Get #1,, MyRec
		If MyRec.КодТовара = 0 Then
			Debug.Print "В файле нет записи с кодом:", Code
		Else: Call PrintRec(MyRec)
		End If
	Next i
	Close #1
End Sub

Из новых деталей отметим следующее. Здесь оператор Seek работает по существу, хотя, конечно, и без него можно было бы обойтись, используя возможности оператора Get. Однако, более важно, обратить внимание на то, что при попытке читать запись с ключом, который не задавался при создании файла (по существу, читать несуществующую запись) не возникает ошибки. Причину этого мы уже объяснили. Поэтому приходится организовывать собственную проверку, как это и сделано в нашей программе. В заключение приведем результаты одного из экспериментов с этой процедурой:

Число обрабатываемых записей --   2 
Код Товара:   8			Цена:   224 
В файле нет записи с кодом:   5